DEMO   ENGLISH   CONFIG (1.0)
  ROOTCAT   S.
  FILES  .
  LEXENTRIES   (DEMO ENGLISH).
  TEMPLATES (DEMO ENGLISH). 
  RULES   (DEMO ENGLISH).
  GOVERNABLERELATIONS    SUBJ OBJ OBJ2 COMP XCOMP OBL OBL-?+.
  SEMANTICFUNCTIONS    ADJUNCT  TOPIC FOCUS POSS STANDARD.
  NONDISTRIBUTIVES    NUM PERS CONJ-FORM.
  EPSILON   e.
OPTIMALITYORDER NOGOOD.

----

DEMO   ENGLISH   RULES (1.0)

   S --> NP: (^ SUBJ)=!
	     (! CASE)=NOM;
 	 VP: ^=!.

   VP --> (AUX)
 	  V: ^=!; 
 	  (NP: (^ OBJ)=! "direct object"
	       (! CASE)=ACC)
 	  (NP: (^ OBJ2)=! "secondary object"
	       (! CASE)=DAT)
 	  (PP: (^ OBL-AG) = !).

   NP --> (D)
 	  N. 

   PP --> P    "this needs to be more complicated"
      	  NP. 

----
DEMO   ENGLISH   TEMPLATES (1.0)

   OPT-TRANS(P) = "template for verbs that can be trans or intrans"
	  { @(TRANS P) 
	  | @(INTRANS P) }. 
	  
 INTRANS(P) = (^ PRED) = 'P<(^SUBJ)>'.

"TRANS(P) = (^ PRED) = 'P<(^SUBJ)(^OBJ)>'." "old Trans template"

DITRANS(P) = (^ PRED) = 'P<(^SUBJ)(^OBJ2)(^OBJ)>'. 

"new TRANS Template"

TRANS (P) = @(PASS (^ PRED)='P<(^ SUBJ) (^ OBJ)>').

"new DITRANS template, leave commented out for now"
"DITRANS (P) = @(PASS (^ PRED)='P<(^ SUBJ) (^ OBJ) (^ OBJ2)>')."

  PASS(SCHEMATA) = {  SCHEMATA   "no passive, just give back subcat frame"
	             | SCHEMATA   "passive"
	              (^ PASSIVE) = +   "mark as such"
	              (^ PARTICIPLE)=c past  "make sure to have a past participle verb"
	              (^ OBJ)-->(^ SUBJ)   "take obj, make subj"
	            { (^ SUBJ)-->(^ OBL-AG)  "either make subj obl-ag"
	            | (^ SUBJ)--> NULL}}.     "or delete" 

   VPRES = @(TENSE pres) 
	   @(MOOD indicative). 

   VPAST = @(TENSE past) 
	  @(MOOD indicative). 

   PASTP = (^ PARTICIPLE) = past. 

   BARE-AGR = { (^ SUBJ NUM) = pl "either it is plural"
	  | (^ SUBJ PERS) ~= 3 "or singular and not 3rd person"
	    (^ SUBJ NUM) = sg}.

   S-AGR = (^ SUBJ PERS) = 3  "for verbs in -s"
	  (^ SUBJ NUM) = sg. 
	  
   TENSE(T) = (^ TENSE) = T.  

   MOOD(M) = (^ MOOD) = M.

   PRED(P) = (^ PRED) = 'P'. 

   COUNT-NOUN(P N) = @(PRED P)
	  (^ NUM) = N
	  (^ PERS) = 3
	  (^ NTYPE) = count. 

----

DEMO ENGLISH LEXICON (1.0)

"all nouns here"

girl 	  N * @(COUNT-NOUN girl sg).

bone 	  N * @(COUNT-NOUN bone sg).

bones 	  N * @(COUNT-NOUN bone pl).

homework  N * @(COUNT-NOUN homework sg).

gorilla	  N *  @(COUNT-NOUN gorilla sg).

gorillas  N *  @(COUNT-NOUN gorilla pl).

banana	  N *  @(COUNT-NOUN banana sg).

bananas	  N *  @(COUNT-NOUN banana pl).

dog 	  N *  @(COUNT-NOUN dog sg).

dogs 	  N *  @(COUNT-NOUN dog pl).

"do NOT have duplicate headwords/lexical entries!!!" 
"walk      N * @(COUNT-NOUN walk sg)." 

"all verbs here"

walk 	  V * @(INTRANS walk)
	      @VPRES
	      @BARE-AGR;
	  N * @(COUNT-NOUN walk sg).
	      
ate 	  V * @(OPT-TRANS eat) "optionally transitive verbs"
	      @VPAST.

eats 	  V * @(OPT-TRANS eat)
	      @VPRES
              @S-AGR. 

drinks   V * @(OPT-TRANS drink)
             @VPRES
             @S-AGR. 

devour 	  V * @(TRANS devour) 
	      @VPRES
	      @BARE-AGR. 

devours  V * @(TRANS devour) 
	     @VPRES
             @S-AGR.

devoured  V * @(TRANS devour) 
              @VPAST
              @PASTP. 

gave 	  V * @(DITRANS give)
	      @VPAST. 

gives     V * @(DITRANS give)
	      @VPRES
	      @S-AGR.

sleeps 	  V * @(INTRANS sleep)
	      @VPRES
              @S-AGR. 

sleep 	  V * @(INTRANS sleep)
              @VPRES
              @BARE-AGR.

"prepositions"

by	  P * (^ PFORM) = by.  "this needs to be more complicated"

"auxiliaries"

was 	  AUX * @(TENSE past)
		@S-AGR. 

"determiners here"

the  D *  (^DEF) = +.

a  D *  (^DEF) = -
        (^ NUM) = sg.

----